Color Code Status for Actor, Use Case

[Michel777]

Hi Forum,

Requirements represent her status  by color, e.g. proposed = yellow, approved= green.

Waht about other elements, like Actors, Use Cases etc ? Is it possible to display the status by color ?

Thnaks, Michel

[Sunshine]

EA out of the box Actors, Use Cases etc aren't provided with the ability to change colours according to status. However you can create a stereotype for that object type and assign a shape script that changes the colour according to the status.
I did something similar to reflect status in a roadmap for work packages. It basically created an icon in top right of shape dependent upon the status of the work package and colour coded it. See the Shape Main part of the code for colouring the shape depending upon the status

Code: [Select]

decoration Icon
{
      scalable ="false";
      orientation = "NE";
      noShadow=true;
      
      if (HasProperty("Status","Implemented"))
    {
            //Black Tick
            setpen(0,0,0,3);
            moveto(0,6);
            lineto(3,10);
            lineto(10,0);
      }
      else if (HasProperty("Status","Redundant"))
    {
            // Red Cross
            setpen(128,0,0,3);
            moveto(0,0);
            lineto(10,10);
            moveto(10,0);
            lineto(0,10);
      }
      else if (HasProperty("Status","In Progress"))
    {
            //Blue Hour glass
            setpen(0,0,128,1);
            moveto(0,0);
            lineto(10,10);
            moveto(10,0);
            lineto(0,10);
            
            setpen(0,0,128,3);
            moveto(0,0);
            lineto(10,0);
            moveto(0,10);
            lineto(10,10);
      }
      else if (HasProperty("Status","Approved"))
    {
      //Green Thumbs up
            setpen(0,64,0,1);
            moveto(15,8);
            //Thumb
            lineto(11,8);
            lineto(6,3);
            lineto(5,0);
            lineto(4,0);
            lineto(3,1);
            lineto(3,3);
            lineto(4,5);
            lineto(5,8);
            lineto(5,8);
            //1st finger
            lineto(2,8);
            lineto(0,9);
            lineto(0,10);
            lineto(1,11);
            lineto(5,11);
            lineto(6,10);
            //2nd finger
            moveto(1,12);
            lineto(2,13);
            lineto(6,13);
            lineto(7,12);
            //3rd finger
            moveto(2,14);
            lineto(3,15);
            lineto(7,15);
            lineto(8,14);
            //4th finger
            moveto(3,16);
            lineto(4,17);
            lineto(8,17);
            lineto(9,15);
            //wrist
            moveto(5,17);
            lineto(9,18);
            lineto(11,17);
            lineto(15,17);
            lineto(16,13);
            lineto(16,10);
            lineto(15,8);
      }
}

shape main
{    
      
      if (HasProperty("Status","Implemented"))
    {
        setfillcolor(210,210,210);
    }
      else if (HasProperty("Status","Approved"))
    {
       setfillcolor(192,220,192);
    }
      else if (HasProperty("Status","Proposed"))
    {
        setfillcolor(247,244,164);
    }
      else if (HasProperty("Status","Redundant"))
    {
        setfillcolor(255,192,203);
            setlinestyle("dash");
    }
      else if (HasProperty("Status","Validated"))
    {
        setfillcolor(192,220,192);
    }
      else if (HasProperty("Status","In Progress"))
    {
        setfillcolor(166,202,240);
    }
      drawnativeshape();
}
 Alternatively if you just want to highlight those object types in a particular status you could create a few diagram filters so it shades/greys/hides objects that aren't in a particular status.

[Eve]

Yes, other elements can display their status colour. There is an 'Applies To' button on the status types dialog. You'll also need to ensure that shadows are being displayed because status colours are displayed on the shadow.